macro "Microscopes Scales [F12]" {


// **********************************************************
// FILE HEADER
// **********************************************************

// MADE WITH THE HELP OF MACROBLOCKS


// NAME OF THE MACRO: SCALE SETTING

// DATE OF LAST MODIFICATION: 30/1/2015

// AUTHOR: Fabrice DUPRAT

// EMAIL: 1.47

// SHORT DESCRIPTION: Setting ImageJ scale for images from various IPMC microscope

// INPUT: Ask which microscope and objective were used

// OUTPUT: Set the correct scale globally for all images



// **********************************************************
// INITIALISATION
// **********************************************************



//---------------------------------------------------------------------------------------------
// !!!!!  LIST OF OBJECTIVES AND SCALES TO BE MODIFIED ACCORDING TO YOU NEEDS !!!!!!!!!!
//---------------------------------------------------------------------------------------------

// Array with the list of microscopes
my_microscope = newArray("AxioObserver Calcium R-1","AxioObserver Calcium R+2", "DMD108 Histologie R+1", "Axiovert 200M Videomicroscope R-1", "Axioplan2 Epifluorescence R-1", "Olympus 2 photons");

// Arrays with the objective list of each microscope
microscope0_objective = newArray("Plan x20", "Fluar x20", "Fluar x40"); 
microscope1_objective = newArray("Plan x10 Optovar x1", "Plan x10 Optovar x1.25", "Plan x10 Optovar x1.6", "Fluar x10 Optovar x1", "Fluar x10 Optovar x1.25", "Fluar x10 Optovar x1.6", "Fluar x20 Optovar x1", "Fluar x20 Optovar x1.25", "Fluar x20 Optovar x1.6", "Fluar x40 Optovar x1", "Fluar x40 Optovar x1.25", "Fluar x40 Optovar x1.6"); 
microscope2_objective = newArray("Macro", "x4", "x10", "x20", "x40", "x63"); 
microscope3_objective = newArray("NeoFluar 10x", "NeoFluar 40x", "PlanApo 10x");
microscope4_objective = newArray("Fluar 10x", "NeoFluar 10x", "NeoFluar 25x", "NeoFluar 40x", "NeoFluar 63x");
microscope5_objective = newArray("PlanFI x20", "PlanFL x40"); 


// Arrays with the coresponding list of scale factor (pixels for 1000 µm) for each objetive
microscope0_scale= newArray(1294,1295,2578); 
microscope1_scale= newArray(643,782,1000,643,782,1000,1286,1557,2000,2568,3113,3983); 
microscope2_scale= newArray(96,630,1579,3180,6353,10013); 
microscope3_scale= newArray(1616,6352,1591); 
microscope4_scale= newArray(1548,1548,4106,6141,9692); 
microscope5_scale= newArray(3120,6190); 

//---------------------------------------------------------------------------------------------
// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
//---------------------------------------------------------------------------------------------


//---------------------------------------------------------------------------------------------
// Dialog to choose the used microscope

// Prepare the dialog window
Dialog.create("Choose your microscope");	 	// Name of dialog window

Dialog.addMessage("IMPORTANT, AT LEAST ONE IMAGE MUST ALREADY BE OPEN");
Dialog.addChoice("Used microscope : ", my_microscope, "") 	// Multiple text choice

// Display the dialog window
Dialog.show();

my_microscope_choice = Dialog.getChoice(); 	// Get the microscope choice (string value)

// Get the index of the microscope choice (0 based numeric value)
for (i=0; i<my_microscope.length; i++) {
	if (my_microscope_choice == my_microscope[i]) {index_microscope_choice = i;}
}


//---------------------------------------------------------------------------------------------
// !!!!!  TO BE MODIFIED ACCORDING TO THE NUMBER OF ABOVE MICROSCOPES !!!!!!!!!!
//---------------------------------------------------------------------------------------------

// Dialog to choose the used objective

// Set the list of objective and scales according to the previous choice of microscope 
if (index_microscope_choice == 0) {
	the_objective = Array.copy(microscope0_objective);
	the_scale = Array.copy(microscope0_scale);
} else if (index_microscope_choice == 1) {
	the_objective = Array.copy(microscope1_objective);
	the_scale = Array.copy(microscope1_scale);
} else if (index_microscope_choice == 2) {
	the_objective = Array.copy(microscope2_objective);
	the_scale = Array.copy(microscope2_scale);
} else if (index_microscope_choice == 3) {
	the_objective = Array.copy(microscope3_objective);
	the_scale = Array.copy(microscope3_scale);
} else if (index_microscope_choice == 4) {
	the_objective = Array.copy(microscope4_objective);
	the_scale = Array.copy(microscope4_scale);
} else if (index_microscope_choice == 5) {
	the_objective = Array.copy(microscope5_objective);
	the_scale = Array.copy(microscope5_scale);
}

//---------------------------------------------------------------------------------------------
// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
//---------------------------------------------------------------------------------------------


// Prepare the dialog window
Dialog.create("Choose your objective");	 // Name of dialog window

Dialog.addChoice("Used objective: ", the_objective, "") 	// Multiple text choice

// Display the dialog window
Dialog.show();

my_objective_choice = Dialog.getChoice(); 	// Get the multiple choice,

// Get the index of the objective choice (0 based numeric value)
for (i=0; i<the_objective.length; i++) {
	if (my_objective_choice == the_objective[i]) {index_objective_choice = i;}
}


//---------------------------------------------------------------------------------------------
// Change the scale according to the choosen objective

run("Set Scale...", "distance="+ the_scale[index_objective_choice] +" known=1000 pixel=1 unit=µm global");

showMessage("SCALE SETTING","The global scale, in µm, is now set for\nMicroscope : "+my_microscope_choice+ "\nObjective: " + my_objective_choice +"\nScale factor: "+ 1000/the_scale[index_objective_choice] +" µm/pixel ("+ the_scale[index_objective_choice]/1000 +" pixels/µm)");



} // end of macro